Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

$ ! Modified: 13-Aug-82/SLP to try MTBs before MTAs
$ WRITE SYS$OUTPUT " "
$ WRITE SYS$OUTPUT "TVAX DEC-10 to VAX File Transfer Utility"
$ WRITE SYS$OUTPUT " "
$ BELL[0,32]= %X07
$ ON WARNING THEN GOTO TRY_MTA
$ ALLOCATE MTB: DUMPER:
$ GOTO GOT_A_DRIVE
$ TRY_MTA:
$ ON WARNING THEN GOTO NODRIVES
$ ALLOCATE MTA: DUMPER:
$ GOT_A_DRIVE:
$ REQUEST/REPLY/TO=TAPES "Please mount TVAX tape for user ''F$PROCESS()' on ''F$LOGICAL("DUMPER")'"
$ ON WARNING THEN GOTO MOUNTERR
$ MOUNT/DENSITY:800/FOREIGN DUMPER: DUMPER
$ ON CONTROL_Y THEN GOTO ABEND
$ DUMPER
FILES
RESTORE []=[*]*.*
GO
EXIT
$ GOTO DONE
$ NODRIVES:
$ IF $SEVERITY .EQ. 4 THEN GOTO FATAL
$ WRITE SYS$OUTPUT BELL,"%TVAX-W-NODRIVES There are no drives currently available."
$ WRITE SYS$OUTPUT "%TVAX-W-NODRIVES Please try again later."
$ FATAL:
$ ON WARNING THEN CONTINUE
$ DISMOUNT DUMPER:
$ DEALLOCATE DUMPER:
$ DEASSIGN DUMPER:
$ EXIT
$ MOUNTERR:
$ WRITE SYS$OUTPUT BELL,"%TVAX-F-MOUNTERR Unable to mount tape on drive."
$ WRITE SYS$OUTPUT "%TVAX-F-MOUNTERR Please see a consultant or an operator."
$ ON WARNING THEN CONTINUE
$ DISMOUNT DUMPER:
$ DEALLOCATE DUMPER:
$ DEASSIGN DUMPER:
$ EXIT
$ ABEND:
$ WRITE SYS$OUTPUT BELL,"%TVAX-F-CNTRLY Abnormal Exit because of Control-Y."
$ ON CONTROL_Y THEN GOTO ABEND
$ INQUIRE ANSWER "Do you wish to dismount your tape <Y OR N>"
$ IF ANSWER .EQS. "N" THEN EXIT
$ DONE:
$ DISMOUNT DUMPER:
$ DEALLOCATE DUMPER:
$ DEASSIGN DUMPER:
$ WRITE SYS$OUTPUT "Tape dismounted..."
$ WRITE SYS$OUTPUT "Processing Completed"
$ DIRECTORY/OUTPUT=SYS$OUTPUT/BRIEF
$ EXIT