Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

     	title	crrscn - Subroutine to retrieve EXEC command line
;
;	Uses RSCAN% Jsys to load the rescan buffer, then actually
;	reads the buffer on behalf of the task. Accepts 2 arguments,
;	the first being an array for the text, the second an integer
;	variable which will receive the number of characters in the command
;	line.
;
	search	vtmac,crcsym
	regdef
	entry	crrscn
	external gtbufa,ptbufa
	forarg	<array,length>
crrscn::efort			;fortran stuff
	movei	t1,.rsini	;initialize buffer
	rscan%			;get the rescan data
	 erjmp	$rserr		;error
	movei	t1,.rscnt	;get number of chars in string
	rscan%			;read
	 nop
	movem	t1,@length(cx)	;store number of chars read
	movn	t3,t1		;make negative for input
	movx	t1,array	;get pointer to o/p area
	call	gtbufa		;may be f77 characters
	move	t2,t1		;require o/p pointer in t2
	movei	t1,.priou	;read rescan data from terminal
	setz	t4,
	sin%			;read the rescan data
	movx	t1,array	;get pointer to o/p area
	call	ptbufa		;copy f77 characters & blank fill
$rserr:	ret			;return to caller
	end