Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

/THE SLOW ONE
/
/
/
/
/
	PMODE
/
/
	EJECT
/
/
/
/
/
/
/
/
	DEFINE	FETCH X<
	JMS	FETCHM
	X>
/
/
	DEFINE	MEMREF<
	JMS	MEMR>
/
/
/
	DEFINE	GETD<
	JMS	DGET>
/
/
/
/
	DEFINE	GETAC<
	JMS	AGET>
/
/
/
	DEFINE	PUTAC<
	JMS	APUT>
/
/
/
/
	DEFINE	END<
	JMS	EXIT>
/
/
/
	DEFINE	PUTD<
	JMS	DPUT>
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
	EJECT
/
/
/
/
/
/
/
/
/
/
/
	*20
AC,	0
LINK,	0
MA,	0
MB,	0
TEMP,	0
INST,	0
PC,	0
LIOT,	0
LINT,	0
IDLE,	0
MEMORY,	0
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/


	EJECT
/
/
/
/
/
/
	*400
/
/
STARTI,	TAD	LIOT
	SZA CLA
	JMP	SNOINT
	TAD	LINT
	SNA
	JMP	SNOINT
	CLA CMA
	TAD	PC
	DCA	PC
	DCA	LINT
	CLA CLL CML RAR
	JMP	SGOTI
/
SNOINT,	FETCH	PC
/
SGOTI,	DCA	INST
	DCA	LIOT
	TAD	INST
	RTL
	RTL
	AND	(7
	TAD	(JMP I	STABLE
	DCA	.+1
	0
/
STABLE,	IAND
	ITAD
	IISZ
	IDCA
	IJMS
	IJMP
	IIOT
	IOPR
/
/
/
/
/
/

/
	EJECT
/
/
/
	*600
/
/
/
/
/
/
IAND,	MEMREF
	GETD
	GETAC
	AND	MB
	PUTAC
	END
/
/
ITAD,	MEMREF
	GETD
	GETAC
	TAD	MB
	PUTAC
	END
/
/
/
IISZ,	MEMREF
	GETD
	ISZ	MB
	SKP
	ISZ	PC
	NOP
	PUTD
	END
/
/
/
IDCA,	MEMREF
	GETAC
	DCA	MB
	PUTAC
	PUTD
	END
/
/
/
/
/
IJMS,	MEMREF
	CLA IAC
	TAD	PC
	DCA	MB
	PUTD
	ISZ	MA
	JMP	IJMP2
	JMP	IJMP2
/
/
/
/
/
IJMP,	MEMREF
IJMP2,	TAD	MA
	DCA	PC
	END
/
/
/
/
/
/
/
IIOT,	ISZ	LIOT
	TAD	INST
	TAD	(-6044
	SNA
	JMP	IOUT
	TAD	(6044-6046
	SZA CLA
	JMP	IGN
/
IOUT,	GETAC
	TAD	(-311
	SZA CLA
	JMP	.+3
	CLA IAC
	DCA	IDLE
	GETAC
	TAD	(-302
	SNA CLA
	DCA	IDLE
/
/
IGN,	TAD	INST
	DCA	IIOTAC
	GETAC
IIOTAC,	0
	SKP
	ISZ	PC
	NOP
	PUTAC
	END
/
/
/
/
/
IOPR=IGN
/
/
/
/
/
/
/
/
/
	EJECT
/
/
/
/
/
	*1000
/
/
/
/
/
/
MEMR,	0
	TAD	INST
	AND	(200
	SZA CLA
	TAD	PC
	AND	(7600
	DCA	MA
	TAD	INST
	AND	(177
	TAD	MA
	DCA	MA
	TAD	INST
	AND	(400
	SNA CLA
	JMP I	MEMR
	TAD	MA
	TAD	(-20
	SMA CLA
	JMP	MOK
	TAD	(-10
	TAD	MA
	SPA CLA
	JMP	MOK
	GETD
	ISZ	MB
	NOP
	PUTD
MOK,	TAD	MB
	DCA	MA
	JMP I	MEMR
/
/
/
/
/
/
AGET,	0
	TAD	LINK
	CLL RAL
	TAD	AC
	JMP I	AGET
/
/
/
/
APUT,	0
	DCA	AC
	RAR
	DCA	LINK
	JMP I	APUT
/
/
/
/
/
/
/
/
/
/
/
/
	EJECT
/
/
/
/
/
/
/
	*1200
/
/
/
/
/
FETCHM,	0
	TAD I	FETCHM
	DCA	MEMORY
	ISZ	FETCHM
/
	CDF	10
	TAD I	MEMORY
	CDF	0
	JMP I	FETCHM
/
/
/
/
/
STOREM,	0
	DCA	STEMP
	TAD I	STOREM
	ISZ	STOREM
	DCA	MEMORY
/
	CDF	10
	TAD	STEMP
	DCA I	MEMORY
	CDF	0
	JMP I	STOREM
/
/
STEMP,	0
/
/
/
/
/
/
/
/
/
EXIT,	0
	JMP	STARTI
/
/
/
/
/
/
DPUT,	0
	TAD	MB
	JMS	STOREM
	MA
	JMP I	DPUT
/
/
/
/
DGET,	0
	FETCH	MA
	JMP I	DGET
/
/
/
/
/
/
/
/
/
/
/
/
/
/
/
	EJECT
/
/
/
/
/
	@