Trailing-Edge
-
PDP-10 Archives
-
decus_20tap1_198111
-
decus/20-0025/gcvsiz.bas
There are 2 other files named gcvsiz.bas in the archive. Click here to see a list.
00020 GO TO 500
00025 DATA 60 , 100 , 29.8
00029 DATA 6E36,0,0
00035 READ A,B,M
00039 PRINT"RATIO OF HIGH/LOW COEFF.=REQUIRED VALVE RANGEABILITY."
00040 PRINT
00041 PRINT"*** THE IDENTITY OF THE VALVE IS"
00045 READ F,P1,P2
00046 IF F=6E36 THEN 9999
00050 PRINT
00055 PRINT
00060 LET N= F/M
00065 LET Q= (N*10.72*520)/14.7
00070 PRINT "WHEN FLOW IN PPH =" F, "FLOW IN SCFH =" Q
00075 PRINT
00080 PRINT "TEMP IN DEG F","INLET PSIG","OUTLET PSIG","PRESS DROP PSI",
00081 PRINT "VALVE COEFF."
00085 IF (P2+14.7)/(P1+14.7) < .5 THEN 100
00090 LET H=(P1+14.7)-(P2+14.7)
00095 GO TO 105
00100 LET H=(P1+14.7)/2
00105 LET G=M/29
00110 FOR T=(A+460) TO (B+460) STEP (B-A)
00115 LET X=SQR((G*T/(H*(P1+P2+29.4))))
00120 LET C0=(Q*X)/963
00125 PRINT (T-460),P1,P2,H,C0
00130 NEXT T
00140 GO TO 45
00500 PRINT"THIS PROGRAM CALCULATES GAS AND VAPOR (BUT NOT STEAM)"
00505 PRINT"CONTROL VALVE COEFFICIENTS AND ALLOWS YOU TO DETERMINE"
00510 PRINT"REQUIRED VALVE RANGEABILITY. REFERENCE IS EQUATION 4 OF"
00515 PRINT"THE VOLUNTARY STANDARD AGREED TO IN NOV.,1961 BY THE"
00520 PRINT"FLUID CONTROLS INSTITUTE, INC."
00525 PRINT
00530 PRINT"WHEN PRESS. DROP IS CRITICAL, THE PROGRAM ASSUMES OUTLET"
00535 PRINT"PRESSURE IS HALF THE ABSOLUTE INLET PRESS. THE PROGRAM"
00540 PRINT"ALSO CONVERTS PRESS. AND TEMP. TO ABSOLUTE."
00545 PRINT
00550 PRINT"TYPE: 20 DATA (ENTER IN ORDER.....MIN. TEMP. IN DEGREES"
00555 PRINT" F, MAX. TEMP. IN DEGREES F, MOLECULAR WEIGHT."
00560 PRINT
00565 PRINT"TYPE: 25 DATA (ENTER DATA IN GROUPS OF 3, AS MANY GROUPS"
00570 PRINT" AS YOU NEED, IN THIS ORDER.....PPH FLOW,INLET"
00575 PRINT" PSIG, OUTLET PSIG, 2ND FLOW, 2ND PRESS., ETC..."
00580 PRINT
00590 PRINT
00595 PRINT"TYPE: RUN"
00600 PRINT
00605 PRINT"TO SIZE MORE VALVES, ENTER MORE DATA IN LINES 20 AND 25"
00610 PRINT"THEN TYPE RUN"
09999 END