Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

!ISAM.CTL	VERSION 12B
!
!USED TO MAKE ISAM.EXE FROM ISAM SOURCE FILES
!THIS FILE RUNS ON EITHER TOPS-20 OR TOPS-10
!SUBMIT WITH COMMAND	SUBMIT ISAM
!
!THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY ONLY BE USED
!  OR COPIED IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
!
!COPYRIGHT (C) 1979, 1981 BY DIGITAL EQUIPMENT CORPORATION
!
!SHOULD BE RUN AFTER COBOL.CTL AND LIBOL.CTL
!OR MAKE SURE THE CORRECT .UNV FILES ARE ON DSK:
!
!INSTALLATION SPECIFIC ASSIGNMENTS SHOULD BE PUT IN THE FOLLOWING FILE:
! ON TOPS-20 IN A TAKE FILE COBOL.CMD
! ON TOPS-10 IN A MIC  FILE COBOL.MIC
!	  OR IN A TECO FILE COBOL.TEC
!NOTE, IN GENERAL THIS CONTROL FILE WILL NOT RUN WITHOUT ONE OF THE ABOVE
!DEFINITION FILES BEING PRESENT.
!
!IF LISTINGS ARE DESIRED, THE EMPTY FILE
!LISTEM.MAC SHOULD BE IN DSK:
!
!TEST FOR WHICH SYSTEM
@GOTO TOPS20	!TOPS20 VERSION
.GOTO TOPS10	!TOPS10 VERSION

TOPS20::
!REQUIRED FILES:
!<FIELD-IMAGE>	CREF.EXE
!		LINK.EXE
!		MACRO.EXE
!		UUOSYM.UNV
!
!<NEW>		PA1050.EXE
!
!<SELF>	ISAM.CTL
!	ISAM.MAC
!	ISAM.HLP
!
!<SELF>	!FROM COBOL & LIBOL BUILD
!	INTERM.UNV
! EITHER
!	LIBOL.REL	(COBOL-68)
! OR
!	C74LIB.REL	(COBOL-74)
!	COBTST.EXE
!
!OUTPUT: ISAM.EXE
!
!OUTPUT LISTINGS: ISAM.LOG, ISAM.HLP
!
@ERROR
@TAKE COBOL.CMD
@IF (ERROR) !IGNORE IT
!
!MAKE A RECORD OF WHAT IS BEING USED.
@GET SYS:PA1050
@INFO VERSION
@GET SYS:MACRO
@INFO VERSION
@GET SYS:LINK
@INFO VERSION
@GET SYS:CREF
@INFO VERSION
!
@VD SYS:PA1050.EXE,SYS:MACRO.EXE,SYS:LINK.EXE,SYS:CREF.EXE,SYS:UUOSYM.UNV,
@CHECK SEQ
@
!
@VD ISAM.*,LIBOL.REL,C74LIB.REL,INTERM.UNV,
@CHECK SEQ
@
!
!ASSEMBLE SOURCES
!
@ERROR %
@TYPE LISTEM.MAC
@IF (ERROR) @GOTO NOLIS1
@ERROR
!
!HERE FOR CREF LISTINGS
!
@MACRO
*ISAM,ISAM/C=ISAM
@IF (ERROR) @GOTO TRUBLE
@CREF
*DSK:ISAM.LZT=ISAM
@IF (ERROR) @PLEASE TROUBLE CREATING ISAM.LZT
@GOTO DONCRF
!
!
!HERE FOR NO CREF LISTINGS
!
NOLIS1::
@ERROR
!
@MACRO
*ISAM=ISAM
@IF (ERROR) @GOTO TRUBLE
!
DONCRF::
!CREATE ISAM.EXE
!
@RUN COBTST
*ANS68
@IF (ERROR) @GOTO ANS74
@LINK
*ISAM.MAP/MAP=ISAM,LIBOL/SEARCH/SYMSEG:HIGH/GO
@IF (ERROR) @GOTO TRUBLE
@SAVE ISAM 0 677
@IF (ERROR) @GOTO TRUBLE
@GOTO CHECK
!
ANS74::
@LINK
*ISAM.MAP/MAP=ISAM,C74LIB/SEARCH/SYMSEG:HIGH/GO
@IF (ERROR) @GOTO TRUBLE
@SAVE ISAM 0 677
@IF (ERROR) @GOTO TRUBLE
!
CHECK::
!SEE WHAT WE GOT:
@VD ISAM.EXE,
@CHECK SEQ
@
@IF (ERROR) @ !IGNORE ANY ERRORS.
!
!TELL OPERATOR HOW WE DID
@PLEASE -- ISAM CREATION SUCCESSFUL
@DELETE ISAM.REL
@EXP
@MODIFY BATCH */DEPEND:-1
@GOTO OK
TRUBLE::@PLEASE -- ISAM CREATION NOT SUCCESSFUL!!!
@GOTO OK

TOPS10::
!
!REQUIRED FILES:
!SYS:		COMPIL.EXE
!		CREF.EXE
!		LINK.EXE + LNK???.EXE
!		MACRO.EXE
!		PIP.EXE
!
!UNV:		UUOSYM.UNV
!
![SELF]	ISAM.CTL
!	ISAM.MAC
!	ISAM.HLP
!
![SELF]	!FROM COBOL & LIBOL BUILD
!	INTERM.UNV
! EITHER
!	LIBOL.REL	(COBOL-68)
! OR
!	C74LIB.REL	(COBOL-74)
!
!OUTPUT:
!	ISAM.EXE
!	ISAM.LOG
!	ISAM.MAP
!
.ERROR
.SET WATCH VERSION
!SET UP THE DEFAULT LOGICAL NAMES
!
.SET DEFAULT PROTECTION 015
.ASSIGN DEC: SYS:
.ASSIGN DEC: UNV:
.ASSIGN DEC: REL:
.ASSIGN DSK: C68:
.ASSIGN DSK: C74:
!IF YOU CAN USE THE PATH COMMAND
.PATH CS:=CBL1:[10,131001]
.PATH SB:=CBL1:[10,131016]
.PATH LIB:/SEARCH=CS:,SB:
!OTHERWISE
!.R SETSRC
!*LIB:[10,131001]
!.ASS LIB: CS:
!.ASSIGN DSK: SB:
.IF (ERROR) !IGNORE IT
!
!SEE WHAT WE ARE USING
.R DIRECT
*TTY:=/CHECKSUM/WIDTH:90 SYS:PIP.EXE,MACRO.EXE,LINK.EXE,LNK???.EXE,DIRECT.EXE,COMPIL.EXE,CREF.EXE
.IF (ERROR) . !IGNORE ANY ERRORS.
.R DIRECT
*TTY:=/CHECKSUM/WIDTH:90 CS:ISAM.*,DSK:INTERM.UNV,LIBOL.REL,C74LIB.REL
.IF (ERROR) . !IGNORE ANY ERRORS.
!ASSEMBLE THE SOURCES:
.TYPE LISTEM.MAC
.IF (ERROR) .GOTO NOLIS1
!
!HERE FOR CREF LISTINGS
.R MACRO
*ISAM,ISAM/C=ISAM
!
.R CREF
*DSK:ISAM.LZT=ISAM
!
.GOTO DONCRF
!
NOLIS1::
.ERROR
.R MACRO
*ISAM=ISAM
.IF (ERROR) .GOTO TRUBLE
!
DONCRF::
!
!CREATE ISAM.EXE
!
.RUN COBTST
*ANS68
.IF (ERROR) .GOTO ANS74
.R LINK
*ISAM.MAP/MAP=ISAM,LIBOL/SEARCH/GO
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:ISAM
.IF (ERROR) .GOTO TRUBLE
.GOTO CHECK
!
ANS74::
.R LINK
*ISAM.MAP/MAP=ISAM,C74LIB/SEARCH/GO
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:ISAM
.IF (ERROR) .GOTO TRUBLE
!
CHECK::
!SEE WHAT WE GOT:
.R DIRECT
*TTY:=/CHECKSUM/WIDTH:90 ISAM.*
.IF (ERROR) . !IGNORE ANY ERRORS.
.DELETE ISAM.REL
!
!TELL OPERATOR HOW WE DID
.PLEASE -- ISAM CREATION SUCCESSFUL
!
!WE CANNOT MIX GALAXY 2 AND GALAXY 4.1
!SO
.DEAS SYS
.IF (ERROR) !
!
.SUB INP:*=/MODIFY/DEPEND:-1
.GOTO OK
TRUBLE::.PLEASE -- ISAM CREATION NOT SUCCESSFUL!!!
OK::!END OF ISAM.CTL