Trailing-Edge
-
PDP-10 Archives
-
k20v7d
-
utilities/save.mic
There is 1 other file named save.mic in the archive. Click here to see a list.
@ENABLE
; Mic file to save KLAD on Magtapes.
;
; Parameters:
; A = Master Structure = 'A:
; B = Magtape = MTA'B:
;
; Type "^P" to continue. Type "^A" to abort.
;
@DEF MTA: MTA0:
=^B
;
@NOERROR
@DEF DSK:
@CONN <UTILITIES>
@DEL SAVE.LOG
;
@ERROR
;
@
@ENABLE
@DAYTIME
;
@DEF DIS: 'A:
@MOU STR DIS:
;
ASSMAG::
@DEF MAG: MTA'B:
@ASSIGN MAG:
@IF (NOERROR) @GOTO REWMAG
;
; ? Can't assign MTA'B:
; Repair problem and type "^P".
=^B
@BACKTO ASSMAG
;
REWMAG::
@REWIND MAG:
@IF (NOERROR) @GOTO PRIME
;
; Put MTA'B: online. Type "^P" when ready.
;
=^B
@BACKTO REWMAG
;
PRIME::
;
@NOERROR
@SET FILE INVISIBLE DIS:<SPOOL>*.*
@SET FILE INVISIBLE DIS:<SYSTEM>DUMP.*
@DEL DIS:<6-DIAGNOSTICS>*.*.*
@EXP DIS:<6-DIAGNOSTICS>
;
;
COPY DIS:<UTILITIES>FRONT-END-BOOT.BIN.* DIS:<ROOT-DIRECTORY>
;
;
@ERROR
;
@COPY DIS:<SYSTEM>2060-MONBIG.EXE.* DIS:<6-DIAGNOSTICS>
@COPY DIS:<SYSTEM>EXEC.EXE.* DIS:<6-DIAGNOSTICS>
@COPY DIS:<SYSTEM>ERRMES.BIN.* DIS:<6-DIAGNOSTICS>
;
;**********************************************************
; *
; The following steps create KLAD-20 BACKUP-TAPE 1 *
; *
; CONTENTS: <SYSTEM>2060-MONBIG.EXE *
; <SYSTEM>EXEC.EXE *
; <SUBSYS>DLUSER.EXE *
; DLUSER-FILE to recreate KLAD-DIRECTORIES *
; <SUBSYS>DUMPER.EXE *
; <SYSTEM>EXEC.EXE,ERRMES.BIN *
; <UTILITIES> *
; <ROOT-DIRECTORY>FRONT-END-SYSTEM-*.BIN *
; *
; Assumptions: 2400 feet MAGTAPE on UNIT 0 *
; *
; Time requirements: Roughly 12-15 min WALL-CLOCK time *
; *
;**********************************************************
;
@GET DIS:<SYSTEM>2060-MONBIG.EXE
@SAV MAG:
@GET DIS:<SYSTEM>EXEC.EXE
@SAV MAG:
@GET DIS:<SUBSYS>DLUSER.EXE
@SAV MAG:
;
@START
*STRUCTURE DIS:
*DUMP MAG:
*EXIT
;
@RESET
@GET DIS:<SUBSYS>DUMPER.EXE
@SAV MAG:
;
@CONN DIS:<SYSTEM>
@START
*TAPE MAG:
*SSNAME KLAD20-AC-7.0-A
*SAVE DIS:<6-DIAGNOSTICS>*.*.* PS:<SYSTEM>*.*.*
*EXIT
;
@ENABLE
@DEL DIS:<6-DIAGNOSTICS>*.*.*
@EXP DIS:<6-DIAGNOSTICS>
@CONN <UTILITIES>
;
@START
*TAPE MAG:
*SSNAME KLAD20-AC-7.0-A <UTILITIES>
*SAVE DIS:<UTILITIES>*.*.* PS:<UTILITIES>*.*.*
*EXIT
@ENABLE
@CONN DIS:<ROOT-DIRECTORY>
;
;*******************************************************************
;This step checks the FE-SYSTEM on DISK-ERRORS ,it takes some time !
;*******************************************************************
;
@RU DIS:<UTILITIES>READFE
*DIS:<ROOT-DIRECTORY>FRONT-END-FILE-SYSTEM.BIN
*COPY DIS:<UTILITIES>FRONT-END-BOOT.BIN DIS:<FE-COPY>FRONT-END-BOOT.BIN
;
@DIS:<SUBSYS>DUMPER
*TAPE MAG:
*SSNAME KLAD20-AC-7.0-A Front-end-system copy
*SAV DIS:<ROOT-DIRECTORY>FRONT-END-*.*.* PS:<FE-COPY>
*EXIT
;
@ENA
@RU DIS:<UTILITIES>READFE
*DIS:<ROOT-DIRECTORY>FRONT-END-FILE-SYSTEM.BIN
*REN DIS:<ROOT-DIRECTORY>FRONT-END-BOOT.BIN DIS:<UTILITIES>*.*.*
@RESET
@CONN <SYSTEM>
@UNLOAD MAG:
;
;
TAPE2::
;*******************************************************************
;
; Now to save the entire -20 side with DUMPER.
;
; Note: To continue at this point with a differnt tape unit
; redefine MAG: (i.e. @"DEF MAG: MTA1:")
;
TAPCHK::
;
; Mount tape 2 on tape drive write enabled and online.
; Type "^P" when ready
;
;*******************************************************************
;
;
=^B
;
; Begin saving entire pack
;
@DUMPER
*TAPE MAG:
*ACCSYS
*REWIND
@IF (ERROR) @BACKTO TAPCHK
*
*SSNAME KLAD20-AC-7.0-A SYSTEM-COPY
*SAVE DIS:<*>*.*.* PS:<*>*.*.*
;
;
; After the second tape (tape 2) is finished mount next
; tape (write enabled) and reissue tape-drive spec
; to DUMPER.
;
; If a second tape drive is available you can
; get it ready and online while the first is
; is still writing and issue the new tape-drive spec
; to DUMPER.
;
; When all areas have been saved type "^P" to
; finish.
;
;***********************************************************
;
=^B
;
@NOERROR
@SET FILE VISIBLE DIS:<SPOOL>*.*
@SET FILE VISIBLE DIS:<SYSTEM>DUMP.*
@ERROR
;
@GOTO END
%ERR::
;
; ERROR in SAVE.MIC
;
END::
@DAY
@KMIC