Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

	TITLE KLPTHR
	SEARCH MONSYM,MACSYM
	.REQUIRE SYS:MACREL

PDL:	BLOCK 50		;PUSH DOWN LIST 
ARGBK0:	107		;GET CONTROL
	7,,0
	0
	0
ARGBK2:	107		;SET THRESHOLD
	7,,2
	-1,,600000	;CLEAR ALL,COUNT ALL,CLEAR ERROR,SET THRESHOLD   
	377
ARGBK1:	107		;RELEASE CONTROL
	7,,1
	0
	0
ARG:	BLOCK 1
INBUF:	BLOCK 5
THRESN:	BLOCK 1

START0:	RESET
	MOVE 17,[-47,,PDL]
START:	HRROI 1,[ASCIZ/
	INPUT THE THRESHOLD NUMBER FOR THE KLIPA :/]
	PSOUT
	CALL NUMIN
	MOVEM 2,THRESN
	MOVE 1,[-4,,ARGBK0]		;GET CONTROL
	DIAG%
	 ERJMP [MOVE 1,[-4,,ARGBK1]	;TRY FORCING A RELEASE
		MOVEI 2,1
		MOVEM 2,ARGBK1+2
		DIAG%
		 ERJMP ERR0
		MOVE 1,[-4,,ARGBK0]	;TRY GETTING CONTROL AGAIN
		DIAG%
		 ERJMP ERR0
		JRST .+1]
	MOVE 1,THRESN
	IORM 1,ARGBK2+2
	MOVE 1,[-4,,ARGBK2]
	DIAG%				;SET THRESHOLD
	 ERJMP	[JRST .+1]
	SETZM ARGBK1+2
	MOVE 1,[-4,,ARGBK1]
	DIAG%				;RELEASE CONTROL
	 ERJMP ERR0
	HALTF
ERR0:	CALL JSERR0
	HALTF

NUMIN:	HRROI 1,INBUF	
	MOVEI 2,5*5
	SETZ 3,
	RDTTY
	ERJMP ERR0
	HRROI 1,INBUF
	MOVEI 3,10
	NIN
	ERJMP ERR0
	RET

	END START0