Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

MODULE DAPCOD=
!Routine to convert system error code to DAP error code
BEGIN

!
! Table of Contents
!
FORWARD ROUTINE
DAPCODE;

!
! LIBRARY & REQUIRE declarations
!
LIBRARY 'DAPLIB';
LIBRARY 'TBL';

!
! Version
!
THIS_IS	[DAPC]	VERSION [1]	EDIT [2]	DATE [16,MAR,79]

%(
 Revision history

[2]	Include File size limit dap error code
[1]	The beginning...

)%
!
! Literals
!

!
! Routines
!
GLOBAL ROUTINE DAPCODE(CODE)=
!Routine to convert system error code to DAP error code
!CODE: system or NETSPL error code
!Returns: DAP error code (MMNNNN) MM=maccode NNNN=miccode
BEGIN
SELECTONE .CODE OF SET
[RMTERR TO RMTERR+%O'177777']: .CODE AND %O'177777';
	!This was a DAP code already with our DAP indicator added on
[FPAERR TO FPAERR+%O'17']: MAC$OPEN+ER$FNM;	!File name syntax errors
[FILFNF]:	MAC$OPEN+ER$FNF;
[FILAEF]:	MAC$OPEN+ER$FEX;
[FILPRT]:	MAC$OPEN+ER$PRV;
[FILFBM]:	MAC$OPEN+ER$FLK;
[FILIPP,FILSNF]: MAC$OPEN+ER$DNF;
[FILNSD,FILOPN]:	MAC$OPEN+ER$DEV;	!Open failure, no such device
[FILNRM]:	MAC$OPEN+ER$QEX;	!No room, directory full, quota exceeded
[INERROR]:	MAC$TRANS+ER$RER;
[OUTERROR]:	MAC$TRANS+ER$WER;
[FILERR TO FILOPN]:	!Catch-all for OPEN errors
		MAC$OPEN+0;
[TIMOUT]:	MAC$TRANS+ER$TMO;
[EXQUOTA]:	MAC$TRANS+ER$QEX;	!Quota exceeded
[DEVFULL]:	MAC$TRANS+ER$FUL;	!Device full
[NODLIM]:	MAC$OPEN+ER$LIM;	!File size limit exceeded...
[NODUNN]:	MAC$OPEN+ER$UNN;	!Node not in node table
[OTHERWISE]:	0;	!Don't know what hit us
TES
END; !DAPCODE
END ELUDOM