Google
 

Trailing-Edge - PDP-10 Archives - decuslib10-02 - 43,50274/z.mac
There are no other files named z.mac in the archive.
TITLE Z - THE JOB STATUS CUSP	V.2
SUBTTL WILL WAGERS  31-JUL-73  

REPEAT	0,<

OPERATIVE UNDER 5S06.  FEEL FREE TO DIRECT COMMENTS TO:

	WILL WAGERS
	%RAPIDATA, INC.
	20 NEW DUTCH LANE
	FAIRFIELD, NJ 07006

>;END IFN REPEAT 0

VMAJOR==2	;VERSION
VMINOR==0	;SUB VERSION
VEDIT==7	;EDIT LEVEL
VWHO==1		;WAGERS

LOC	<.JBVER==137>;END LOC
BYTE	(3)VWHO(9)VMAJOR(6)VMINOR(18)VEDIT

RELOC

;ACCUMULATORS, REGISTERS, AC'S, FAST MEMORY, ETC

P==17		;PUSH DOWN LIST POINTER


;PRIVILEGE BIT DEFINITIONS

JP.MET==40000	;METER UUO PRIVILEGE
JP.POK==20000	;POKE  UUO
JP.CCC==10000	;CPU SPECIFICATION CHANGE 
JP.NSP==200	;UNSPOOL CAPABILITY
JP.RTT==20	;REAL TIME TRAP ABILITY
JP.LCK==10	;LOCK  UUO
JP.TRP==4	;TRPSET UUO
JP.SPA==2	;PEEK  UUO AT ALL OF CORE
JP.SPM==1	;PEEK  UUO AT MONITOR ONLY

;WATCH BIT DEFINITIONS


JW.WDY==200000	;TIME OF DAY IS TO APPEAR AUTOMATICALLY
JW.WRN==100000	;RUNTIME
JW.WWT==40000	;WAIT TIME
JW.WDR==20000	;DISK READS
JW.WDW==10000	;DISK WRITES
JW.WVR==4000	;VERSION NUMBERS


;SPOOLING CONTROL BIT DEFINITIONS

JS.PLP==1	;LINE PRINTER
JS.PPL==2	;PLOTTER
JS.PPT==4	;PAPER TAPE PUNCH
JS.PCP==10	;CARD PUNCH
JS.PCR==20	;CARD READER


;MORE CONVENIENT OPCODES

OPDEF CALL	[PUSHJ	P,]
OPDEF RETURN	[POPJ	P,]
OPDEF LOAD	[MOVE]
OPDEF LOADI	[MOVEI]
OPDEF LOADPC	[JRST]
OPDEF NOOP	[JFCL]
OPDEF PRINT	[OUTSTR]
OPDEF TYPE	[OUTCHR]
OPDEF STORE	[MOVEM]
PAGE
..:	NOOP		;ALLOW FOR FUTURE CCL ENTRY POINT
		 RESET	;GOOD HABIT
		 HRLZI	-1	;PREPARE GETTAB UUO FOR THIS JOB
		 HRRI	6	;.GTPRV TABLE
		 GETTAB
		   NOOP		;POSSIBLY SHOULD GIVE ERROR INDICATION
		 STORE	STATUS	;SAVE FOR LATER
		 LDB	HPQBYT	;GET THE HIGHEST POSSIBLE HIGH PRIORITY QUEUE
		 ADDI	60	;ASCIIZE
		 TYPE
		 PRINT	[ASCIZ . :HIGHEST PRIORITY QUEUE PERMISSIBLE
.]
		 LDB	DPRBYT	;GET HIGHEST POSSIBLE DISK PRIORITY
		 CAIN	4	;***BUG***
		   CLEAR
		 CAIE
		   CALL	[CAIG	4	;INVERTED SIGN
			   PRINT	[ASCIZ .-.]
			 RETURN ]
		 ANDI	3	;LOSE SIGN IF POSITIVE
		 ADDI	60	;ASCIIZE
		 TYPE
		 PRINT	[ASCIZ . :HIGHEST DISK PRIORITY  PERMISSIBLE
.]
		 HRLZI	777777	;SETUP AGIN
		 HRRI	36	;.GTSPL THIS TIME
		 GETTAB
		   NOOP
		 STORE	STATUS+2	;SAVE
		 LDB	DPIBYT		;GET DISK PRIORITY
		 CAIN	4
		   CLEAR
		 CAIE
		   CALL	[CAIL	4
			 PRINT	[ASCIZ .-.]
			 RETURN ]
		 ANDI	3		;LOSE SIGN IF POSITIVE
		 ADDI	60		;ASCIIZE
		 TYPE
		 PRINT	[ASCIZ . :CURRENT DISK PRIORITY

ALLOWED USE OF:
.]
		 LOAD	STATUS
		 TLNN	JP.MET+JP.POK+JP.CCC+JP.NSP+JP.RTT+JP.LCK+JP.TRP+JP.SPA+JP.SPM
		   CALL	[PRINT	[ASCIZ . NO PRIVILEGED UUO'S
.]
			 CLEAR
			 RETURN ]
		 TLNE	JP.MET	;METER ?
		   CALL	[PRINT	[ASCIZ	. METER UUO
.]
			 RETURN ]
		 TLNE	JP.POK	;POKE ?
		   CALL	[PRINT	[ASCIZ	. POKE UUO
.]
			 RETURN ]
		 TLNE	JP.CCC	;CPU SPECIFICATION CHANGE ?
		   CALL	[PRINT	[ASCIZ	. CPU SPECIFICATION CHANGE
.]
			 RETURN ]
		 TLNE	JP.NSP	;UNSPOOL ?
		   CALL	[PRINT	[ASCIZ	. DEVICE UNSPOOLING
.]
			 RETURN ]
		 TLNE	JP.RTT	;REALTIME STUFF ?
		   CALL	[PRINT	[ASCIZ	. RTTRP UUO
.]
			 RETURN ]
		 TLNE	JP.LCK
		   CALL	[PRINT	[ASCIZ	. LOCK UUO
.]
			 RETURN ]
		 TLNE	JP.TRP	;TRPSET ?
		   CALL	[PRINT	[ASCIZ	. TRPSET UUO
.]
			 RETURN ]
		 TLNE	JP.SPA	;PEEK AT CORE ?
		   CALL	[PRINT	[ASCIZ	. SPY/PEEK AT ALL OF CORE
.]
			 TLZ	JP.SPM	;DON'T NEED BOTH MESSAGES
			 RETURN ]
		 TLNE	JP.SPM	;PEEK/SPY AT MONITOR ?
		   CALL	[PRINT	[ASCIZ	. SPY/PEEK AT MONITOR ONLY
.]
			 RETURN ]
		 HRLZI	-1	;SETUP FOR ANOTHER GETTAB
		 HRRI	35	;.GTWCH TABLE
		 GETTAB
		   NOOP		;ERROR MESSAGE DESIREABLE ?
		 MOVEM	STATUS+1
		 PRINT	[ASCIZ .
WATCH: .]
		 TLNN	JW.WDY+JW.WRN+JW.WWT+JW.WDR+JW.WDW+JW.WVR
		   CALL	[PRINT	[ASCIZ . NONE
.]
			 CLEAR
			 RETURN ]
		 TLNE	JW.WDY
		   CALL	[PRINT	[ASCIZ .
 DAY TIME.]
			 RETURN ]
		 TLNE	JW.WRN
		   CALL	[PRINT	[ASCIZ .
 RUN TIME.]
			 RETURN ]
		 TLNE	JW.WWT
		   CALL	[PRINT	[ASCIZ .
 WAIT TIME.]
			 RETURN ]
		 TLNE	JW.WDR
		   CALL	[PRINT	[ASCIZ .
 DISK READS.]
			 RETURN ]
		 TLNE	JW.WDW
		   CALL	[PRINT	[ASCIZ .
 DISK WRITES.]
			 RETURN ]
		 TLNE	JW.WVR
		   CALL	[PRINT	[ASCIZ .
 VERSION NUMBERS.]
			 RETURN ]
		 PRINT	[ASCIZ .
SPOOLED DEVICES:.]
		 LOAD	STATUS+2
		 TRNN	JS.PLP+JS.PPL+JS.PPT+JS.PCP+JS.PCR
		   CALL	[PRINT	[ASCIZ . NONE .]
			 CLEAR
			 RETURN ]
		 TRNE	JS.PLP
		   PRINT	[ASCIZ . LPT .]
		 TRNE	JS.PPL
		   PRINT	[ASCIZ . PLT .]
		 TRNE	JS.PPT
		   PRINT	[ASCIZ . PTP .]
		 TRNE	JS.PCP
		   PRINT	[ASCIZ . CDP .]
		 TRNE	JS.PCR
		   PRINT	[ASCIZ . CDR .]
		 PRINT	[ASCIZ .
.]
		 EXIT
JOB:	BLOCK	1
STATUS:	BLOCK	3
DPIBYT:	POINT	3,STATUS+2,26
HPQBYT:	POINT	2,STATUS,0
DPRBYT:	POINT	4,STATUS,5
		END	..	;C'EST FINIS