Trailing-Edge
-
PDP-10 Archives
-
dbmsv5a
-
dbms10.ctl
There are no other files named dbms10.ctl in the archive.
;DBMS10.CTL V(EDIT)==5A(12)
;USED TO LOAD SCHEMA PROCESSOR, FORTRAN PRE-PROCESSOR, DBINFO,
;DBMEND, DAEMDB, FORTRAN RUN-TIME SYSTEM, COBOL RUN-TIME SYSTEM(S)
;
;***** WARNING---THIS CTL FILE IS USED TO BUILD DBMS-10 ON
; THE DEVELOPMENT SYSTEMS IN MARLBORO. IT IS NOT
; GUARANTEED TO RUN ON ANY OTHER SYSTEM. THE USER
; SHOULD CHECK THIS CTL FILE FOR ANY INSTALLATION
; DEPENDENT ITEMS.
;
;SUBMIT WITH COMMAND .SUBMIT DBMS10/TIME:10000
;
;COPYRIGHT 1975,1976,1977,1978,1979 DIGITAL EQUIPMENT CORP., MARLBORO, MASS.
;
;REQUIRED FILES:
;DEC: PIP (LATEST RELEASED VERSIONS)
; DIRECT
; CREF
; MAKLIB
; LINK+LNK*
;REL: SCAN.REL
; WILD.REL
; HELPER.REL
;
;[SELF]: DBSANY.REL DBS10.REL DBSFOR.REL DBSCOB.REL
; GENME1.REL GENMS1.REL GENIO1.REL
; DBMS10.CTL DBMS5.RND DBMS5A.RND
; SCHEMA.CMD SCHEMA.HLP
; FORDM1.CMD FORDML.HLP
; DBMEN1.CMD DBMEND.HLP
; DBINF1.CMD DBINFO.HLP
; DAEMD1.CMD DAEMDB.HLP
; DBCS18.CMD DBCS14.CMD DBCS1F.CMD
; DDLANY.REL DDL10.REL
; FMLANY.REL FML10.REL
; MNDANY.REL MND10.REL
; INFANY.REL INF10.REL
; DABANY.REL DAB10.REL
; STRHI.REL SCHIO1.REL
;
;
;***** EXAMINE SECTION 6 OF DBMS10.DOC BEFORE SUBMITTING THIS CTL FILE.
; IF APPLICABLE REBUILD COBOL, CBL74, LIBOL, C74LIB AND/OR FOROTS BEFORE
; RUNNING THIS CTL FILE
;
;***** IF YOU DESIRE COBOL-68 DBMS-10 SUPPORT, YOU MUST INCLUDE
; A COPY OF THE LATEST RELEASED LIBOL.REL AND LIBSHR.REL IN YOUR AREA.
;
;
;***** IF YOU DESIRE COBOL-74 DBMS-10 SUPPORT, YOU MUST INCLUDE
; A COPY OF THE LATEST RELEASED C74LIB.REL AND C74SHR.REL IN YOUR AREA.
;
;
;***** IF YOU WISH TO BUILD A FORTRAN-10/DBMS-10 RUN-TIME SYSTEM, YOU
; MUST INCLUDE A COPY OF THE LATEST RELEASED FORLIB.REL IN YOUR AREA.
;
;
;OUTPUT: SCHEMA.EXE FORDML.EXE DBMEND.EXE DBINFO.EXE DAEMDB.EXE
; SCHEMA.MAP FORDML.MAP DBMEND.MAP DBINFO.MAP DAEMDB.MAP
;
; IF BUILDING A COBOL-68 SYSTEM: C68OTS.EXE,C68OTS.MAP, AND LIBOL.REL
; IF BUILDING A COBOL-74 SYSTEM: C74OTS.EXE,C74OTS.MAP, AND C74LIB.REL
; IF BUILDING A FORTRAN SYSTEM: FDBOTS.EXE,FDBOTS.MAP, AND FORLIB.REL
;
;OUTPUT LISTINGS: DBMS10.LOG, DBMS10.DOC(3), *.MAP
;
; **** WILL BUILD JUST THE DESIRED OTS'S
;FOR IN-HOUSE USE ONLY
.R SETSRC
*C DSKB
*T
;END OF IN-HOUSE INSERTION
;USE LATEST SOFTWARE AND RECORD WHAT IS USED
.ASS DEC SYS
.SET WATCH VERSION
.R DIRECT
*TTY:/CHECKSUM=SYS:DIRECT+MAKLIB+LINK+LNK*+SCAN.REL+WILD.REL+HELPER.REL
.R DIRECT
*TTY:/CHECKSUM=DBS*.REL,SCHIO1.REL,DBMS5.RND,DBMS5A.RND,DBMS10.CTL,DBCS1?.CMD,*.HLP
.IF (ERROR) .GOTO TRUBLE
.GOTO QCOBOL
; **** CAUSE ALL THE SOFTWARE TO BE REBUILT BY SPECIFYING /TAG:DBALL
DBALL::
;FOR IN-HOUSE USE ONLY
.R SETSRC
*C DSKB
*T
;END IF IN-HOUSE ONLY INSERTION
; **** WILL BUILD JUST THE DESIRED OTS'S
;USE LATEST SOFTWARE AND RECORD WHAT IS USED
.ASS DEC SYS
.SET WATCH VERSION
.R DIRECT
*TTY:/CHECKSUM=SYS:DIRECT+MAKLIB+LINK+LNK*+SCN7.REL+WILD.REL+HELPER.REL
.R DIRECT
*TTY:/CHECKSUM=DDL*.REL,FML*.REL,MND*.REL,DBS*.REL,DAB*.REL,INF*.REL,GEN*.REL,STRHI.REL,SCHIO1.REL,DBMS5.RND,DBMS5A.RND,DBMS10.CTL,?????1.CMD,DBCS1?.CMD,*.HLP
.IF (ERROR) .GOTO TRUBLE
;CREATE SCHEMA PROCESSOR
;
.R LINK
*@SCHEM1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:SCHEMA
.IF (ERROR) .GOTO TRUBLE
;
;CREATE FORTRAN PRE-PROCESSOR
;
.R LINK
*@FORDM1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:FORDML
.IF (ERROR) .GOTO TRUBLE
;
;CREATE BACKUP/RECOVERY UTILITY
;
.R LINK
*@DBMEN1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DBMEND
.IF (ERROR) .GOTO TRUBLE
;
;CREATE INFO-GENERATING UTILITY
;
.R LINK
*@DBINF1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DBINFO
.IF (ERROR) .GOTO TRUBLE
;
;CREATE BACKGROUND MTA FACILITY
;
.R LINK
@DAEMD1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DAEMDB
.IF (ERROR) .GOTO TRUBLE
;
QCOBOL::
;BUILD COBOL-68 INTERFACE IF LIBOL.REL IS AVAILABLE
;
.ERROR %
.R DIRECT
*TTY:=LIBOL.REL
.IF (ERROR) .GOTO NOC68
.ERROR
;
.R MAKLIB
*LIBOL=LIBOL/DELETE:RSVGAT
*LIBOL=LIBOL/DELETE:RESOLV
*COBFUN.TMP=LIBOL/EXTR:COBFUN
*LIBOL=LIBOL,DBSCOB/APPEND,DBS10/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO1/APPEND
*LIBOL=LIBOL/INDEX
.DEL COBFUN.TMP
;
.R LINK
*@DBCS18
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:C68OTS
.IF (ERROR) .GOTO TRUBLE
NOC68::
.ERROR
;
QCBL74::
;BUILD COBOL-74 INTERFACE IF C74LIB.REL IS AVAILABLE
;
.ERROR %
.R DIRECT
*TTY:=C74LIB.REL
.IF (ERROR) .GOTO NOC74
.ERROR
;
.R MAKLIB
*C74LIB=C74LIB/DELETE:RSVGAT
*C74LIB=C74LIB/DELETE:RESOLV
*COBFUN.TMP=C74LIB/EXTR:COBFUN
*C74LIB=C74LIB,DBSCOB/APPEND,DBS10/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO1/APPEND
*C74LIB=C74LIB/INDEX
.DEL COBFUN.TMP
;
.R LINK
*@DBCS14
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:C74OTS
.IF (ERROR) .GOTO TRUBLE
NOC74::
.ERROR
;
QFORT::
;BUILD FORTRAN INTERFACE IF FORLIB.REL IS AVAILABLE
;
.ERROR %
.R DIRECT
*TTY:=FORLIB.REL
.IF (ERROR) .GOTO NOFORT
.ERROR
;
.R MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFOR/APPEND,DBS10/APPEND,DBSANY/APPEND,SCHIO1/APPEND
*FORLIB=FORLIB/INDEX
;
.R LINK
*@DBCS1F
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:FDBOTS
.IF (ERROR) .GOTO TRUBLE
NOFORT::
.ERROR
;
;HAVE BUILT EVERYTHING, NOW CLEANUP
;
;BUILD AND PRINT DOC FILE
;
.ERROR %
.R RUNOFF
*DBMS5=DBMS5
*DBMS5A=DBMS5A
.IF (ERROR) .PLEASE -- COULD NOT CREATE DBMS10.DOC???
.ERROR
; ***** IN-HOUSE USE ONLY
.DEASSIGN SYS:
; ***** END IN-HOUSE ONLY
.PRINT DBMS5.DOC/COPIES:3,DBMS5A.DOC/COPIES:3,*.MAP/DISPOSE:DELETE
.IF (ERROR) .PLEASE -- COULD NOT PRINT DOC AND/OR MAP FILES???
;
;SEE WHAT WE GOT
;
.R DIRECT
*TTY:/CHECKSUM=SCHEMA.*,FORDML.*,DBMEND.*,DBINFO.*,DAEMDB.*,???OTS.*
*TTY:/CHECKSUM=LIBOL.REL,C74LIB.REL,FORLIB.REL
;
;TELL HOW WE DID
;
.PLEASE -- DBMS-10 CREATION SUCCESSFUL!!!
.GOTO ENDOF
TRUBLE::
.PLEASE -- DBMS-10 CREATION NOT SUCCESSFUL???
ENDOF::.;[ END OF DBMS10.CTL ]