Google
 

Trailing-Edge - PDP-10 Archives - cobol12c - getgen.mac
There are 7 other files named getgen.mac in the archive. Click here to see a list.
TITLE	GETGEN FOR COBOL V12C
SUBTTL	INPUT ROUTINES FOR GENFIL	AL BLACKINGTON/CAM



	SEARCH	COPYRT
	SALL

;COPYRIGHT (C) DIGITAL EQUIPMENT CORPORATION 1974, 1985
;ALL RIGHTS RESERVED.
;
;THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
;ONLY  IN  ACCORDANCE  WITH  THE  TERMS  OF  SUCH LICENSE.

	SEARCH	P
	%%P==:%%P

;EDITS
;V10*****************
;NAME	DATE		COMMENTS
;********************


TWOSEG
	.COPYRIGHT		;Put COPYRIGHT statement in .REL file.

RELOC	400000

	ENTRY	GETGEN	;GET TWO WORDS
	ENTRY	SETGEN	;SET UP GENFIL FOR INPUT
	ENTRY	SETSEG	;SET UP GENFIL TO READ NEXT SECTION

	EXTERNAL DEVDED, KILL

GETGEN:	AOS	GENWRD		;BUMP WORD COUNTER

	SOSG	GENBHI+2
	PUSHJ	PP,GETGN2
	ILDB	W1,GENBHI+1

	SOSG	GENBHI+2
	PUSHJ	PP,GETGN2
	ILDB	W2,GENBHI+1

	POPJ	PP,

GETGN2:	IN	GEN,
	  POPJ	PP,

GETGN3:	MOVEI	CH,GENDEV
	JRST	DEVDED
;SET UP GENFIL FOR INPUT

SETGEN:	MOVE	TA,GENBUF
	MOVEM	TA,.JBFF##
	INBUF	GEN,2

	MOVE	I1,GENHDR
	MOVE	I2,GENHDR+1
	SETZB	I3,I4
	LOOKUP	GEN,I1
	  JRST	KNOGEN

	HLRZ	TA,PROGST
	MOVEM	TA,GENWRD
	CAIN	TA,100
	POPJ	PP,

	JRST	SETSG1

;CANNOT FIND GENFIL

KNOGEN:	TTCALL	3,[ASCIZ "GENFIL not found
"]
	JRST	KILL
;SET UP GENFIL TO READ NEXT SECTION.
;ENTER WITH RH OF TA POINTING TO A PROTAB ENTRY

SETSEG:	ANDI	TA,77777
	ADD	TA,PROLOC
	HLRZ	TA,1(TA)
	CAMN	TA,GENWRD
	POPJ	PP,

	MOVEM	TA,GENWRD

SETSG1:	CALLI	GEN,$WAIT	;WAIT FOR I/O TO CEASE
	ROT	TA,-6
	USETI	GEN,(TA)

	MOVE	TE,GENBHI	;GET ADDRESS OF BUFFER
	MOVE	TE,0(TE)	;GET ADDRESS OF NEXT BUFFER
	SKIPGE	0(TE)		;ANYTHING IN NEXT BUFFER?
	IN	GEN,		;YES--SKIP OVER IT
	  CAIA
	JRST	GETGN3

	IN	GEN,
	  CAIA
	JRST	GETGN3

	ROT	TA,7
	ANDI	TA,177
	ADDM	TA,GENBHI+1
	SUBI	TA,1
	MOVNS	TA
	ADDM	TA,GENBHI+2

	POPJ	PP,


EXTERNAL GENBHI,GENDEV,GENBUF,GENHDR,GENWRD
EXTERNAL PROGST,PROLOC

	END