Google
 

Trailing-Edge - PDP-10 Archives - bb-m780d-sm - monitor-sources/ldinit.mac
There are 48 other files named ldinit.mac in the archive. Click here to see a list.
; UPD ID= 8540, RIP:<7.MONITOR>LDINIT.MAC.2,   9-Feb-88 17:03:55 by GSCOTT
;TCO 7.1218 - Update copyright date.
; UPD ID= 2301, SNARK:<6.1.MONITOR>LDINIT.MAC.16,  19-Jul-85 16:41:16 by MOSER
;TCO 6.1.1492 - MORE JFNS NO SZCOD
;Add CPYRT macro so copyright shows up in LDINIT.REL
; UPD ID= 2097, SNARK:<6.1.MONITOR>LDINIT.MAC.12,   3-Jun-85 15:41:17 by MCCOLLUM
;TCO 6.1.1406  - Update copyright notice.
; UPD ID= 4914, SNARK:<6.MONITOR>LDINIT.MAC.11,  10-Oct-84 17:10:07 by GLINDELL
;TCO 6.1.1021 - 6.1 address space
;	Add XRCOD and XNCOD psects
; UPD ID= 4525, SNARK:<6.MONITOR>LDINIT.MAC.10,  13-Jul-84 20:11:25 by PURRETTA
;Update copyright notice
; UPD ID= 3632, SNARK:<6.MONITOR>LDINIT.MAC.9,   1-Feb-84 22:08:32 by MURPHY
;Add ERCOD and ENCOD for extended code, remove SYVAR.
; UPD ID= 2809, SNARK:<6.MONITOR>LDINIT.MAC.8,   9-Aug-83 11:47:25 by MURPHY
;More 6.1525 - Add SZCOD psect for section 0 code.
; UPD ID= 2564, SNARK:<6.MONITOR>LDINIT.MAC.7,   7-Jun-83 17:03:22 by MURPHY
;TCO 6.1525 - Remove JSVAR and PSVAR psects - do them in STG only.
; UPD ID= 2408, SNARK:<6.MONITOR>LDINIT.MAC.6,   3-May-83 16:07:42 by COBB
;TCO 6.1639 - ?s to PRINTX messages...
; UPD ID= 2226, SNARK:<6.MONITOR>LDINIT.MAC.5,   8-Apr-83 17:55:32 by MURPHY
;TCO 6.1525 - Get rid of NPVAR.
; UPD ID= 186, SNARK:<6.MONITOR>LDINIT.MAC.4,   5-Nov-81 17:34:19 by HALL
;TCO 6.1000 - Remove CPU from JSTAB. Microcode now supplies it
; UPD ID= 419, SNARK:<5.MONITOR>LDINIT.MAC.2,  11-Apr-80 13:50:32 by HALL
;ADD PSECT RSDAT TO PBEGIN INVOCATION
;<4.MONITOR>LDINIT.MAC.10, 21-Jul-79 14:14:06, EDIT BY GILBERT
;REMOVE EXP 0 INSERTED IN LDINIT.MAC.8 -- LINK BUG HAS BEEN FIXED.
;<4.MONITOR>LDINIT.MAC.9,  4-Mar-79 18:10:12, EDIT BY KONEN
;UPDATE COPYRIGHT FOR RELEASE 4
;<4.MONITOR>LDINIT.MAC.8, 15-Jan-79 07:40:31, EDIT BY GILBERT
;More TCO 4.2155:
;	Change SYTBL to SYVAR.
;	Add an EXP 0 to bypass a LINK bug.
;<4.MONITOR>LDINIT.MAC.7,  8-Jan-79 06:49:49, EDIT BY GILBERT
;TCO 4.2155 - Implement hidden symbol tables:
;	Make names of PSECT start labels uniform.
;<4.MONITOR>LDINIT.MAC.6,  3-Jan-79 20:24:15, EDIT BY GILBERT
;SUPPRESS PSECT START PAGE NUMBERS TO DDT TYPEOUT
;<4.MONITOR>LDINIT.MAC.5, 10-Oct-78 09:55:49, EDIT BY MILLER
;SMALL CHANGE TO DEFJS
;<4.MONITOR>LDINIT.MAC.4, 16-Aug-78 02:02:27, Edit by MCLEAN
;<4.MONITOR>LDINIT.MAC.3, 16-Aug-78 01:49:51, Edit by MCLEAN
;FIX IT SO .EXEC ENTRY IS SECTION 1
;<4.MONITOR>LDINIT.MAC.2,  4-Aug-78 23:31:59, Edit by MCLEAN
;MAKE UJSYS0 BE SECTION 1

;	COPYRIGHT (c) DIGITAL EQUIPMENT CORPORATION 1976, 1988.
;	ALL RIGHTS RESERVED.
;
;	THIS SOFTWARE IS FURNISHED UNDER A  LICENSE AND MAY BE USED AND  COPIED
;	ONLY IN  ACCORDANCE  WITH  THE  TERMS OF  SUCH  LICENSE  AND  WITH  THE
;	INCLUSION OF THE ABOVE  COPYRIGHT NOTICE.  THIS  SOFTWARE OR ANY  OTHER
;	COPIES THEREOF MAY NOT BE PROVIDED  OR OTHERWISE MADE AVAILABLE TO  ANY
;	OTHER PERSON.  NO  TITLE TO  AND OWNERSHIP  OF THE  SOFTWARE IS  HEREBY
;	TRANSFERRED.
;
;	THE INFORMATION IN THIS  SOFTWARE IS SUBJECT  TO CHANGE WITHOUT  NOTICE
;	AND SHOULD  NOT  BE CONSTRUED  AS  A COMMITMENT  BY  DIGITAL  EQUIPMENT
;	CORPORATION.
;
;	DIGITAL ASSUMES NO  RESPONSIBILITY FOR  THE USE OR  RELIABILITY OF  ITS
;	SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY DIGITAL.
	SEARCH PROLOG,MONSYM,MACSYM
	TITLE LDINIT
	CPYRT
	ENTRY $LDINIT
	$LDINIT==:0
	SALL

DEFINE PBEGIN(PSECT)<
    IRP PSECT,<
	.PSECT PSECT
PSECT::	BLOCK 0
	PSECT'P==:PSECT_-PGSFT
	.ENDPS PSECT
    >
>

PBEGIN <RSCOD,INCOD,RSDAT,PPVAR,RSVAR>
PBEGIN <NRCOD,BGSTR,BGPTR,NRVAR,ERCOD,ENCOD>
  IFE FTNSPSRV < ;[6.1]
PBEGIN <XRCOD,XNCOD>
  >

MAXJS==777			;MAXIMUM JSYS NUMBER
;JSYS DISPATCH TABLE.

	.PSECT RSCOD
JSTAB::

;ON PASS1 DEFINE THE SLOTS TAKEN BY REAL JSYS DEFINITIONS

IF1,<
   DEFINE DEFJS (NAM,VAL,SECN,COD,OLDNEW) <
      IFG <VAL-MAXJS>,<PRINTX ?*** JSYS NAM .GT. 777 ***>
      IFDIF <COD>,<NIM>,<
	IFB <SECN>,<
	  %%'VAL==.'NAM##	;;DEFINE SLOT AND REFERENCE SYMBOL
	>
	IFNB <SECN>,<
	  %%'VAL==SECN##,,.'NAM##
	>
      >
   >

;NOW EXPAND JSYS LIST

	JSLIST

> ;;; END OF IF1

;ON PASS2 FILL TABLE WITH DEFINES ENTRIES AND DEFAULTS IF
; SLOT IS EMPTY

IF2,<
   DEFINE MAKENT (SLOT) <
  IFNDEF %%'SLOT,<MSEC1+,,UJSYS0##>
  IFDEF %%'SLOT,<
	%%'SLOT
	PURGE %%'SLOT
      >
   >

%%CNT==0		;INIT COUNTER
REPEAT MAXJS+1,<			;;REPEAT FROM 0 TO 777
	MAKENT (\%%CNT)	;MAKE AN ENTRY
	%%CNT==%%CNT+1
>

> ;;; END IF2


	.ENDPS RSCOD

	END