Trailing-Edge
-
PDP-10 Archives
-
ap-c796e-sb
-
gripe.ctl
There is 1 other file named gripe.ctl in the archive. Click here to see a list.
;JOB%1(20) TO MAKE GRIPE.SAV FROM GRIPE.MAC
;SUBMIT WITH COMMAND .QUEUE I:=GRIPE/RESTART:1
;
;REQUIRED FILES: (LATEST RELEASED VERSIONS)
;[10,7] PIP.SHR
; DIRECT.SHR
; COMPIL.SHR
; MACRO.SHR
; LINK.SHR
; LNK???.SHR
; JOBDAT.REL
; CREF.SHR
; C.MAC
;[SELF] GRIPE.MAC
; GRP???.RND
; GRIPE.HLP
;
;OUTPUT FILE:
; GRIPE.SAV
;
;OUTPUT LISTINGS:
; GRIPE MAP
; GRIPE CREF LISTING
; GRIPE.LOG
; GRIPE.DOC
;
;
.SET WATCH VERSION
;COPY FILES FROM [10,7] AND USE PRIVATE "SYS:"
.RUN DSK:PIP[10,7]
*/X_DSK:PIP.SHR[10,7],COMPIL.SHR[10,7],MACRO.SHR[10,7],LINK.SHR[10,7]
*/X_DSK:CREF.SHR[10,7],C.MAC[10,7],DIRECT.SHR[10,7],JOBDAT.REL[10,7],LNK???.SHR
;
.ASSIGN DSK: SYS:
;
;MAKE PARAMETER FILE
.COPY U.MAC=TTY:
%.C==-3
;
;COMPILE, LOAD, AND SAVE; PRODUCING MAP AND CREF FILE
.LOAD/LINK /MAP:GRIPE /CREF /COMPILE U.MAC+C.MAC,GRIPE.MAC %"CONT:ZERO"
.SAVE DSK:GRIPE
.VERSION
.IF (ERROR) .E 137
;
;TRY IT JUST TO MAKE SURE IT WORKS
.RUN DSK:GRIPE
=THIS IS A GRIPE TEST FROM GRIPE.CTL
.RUN DSK:DIRECT[10,7]
*TTY:/CHECKSUM=GRIPE.SAV,GRIPE.HLP,GRIPE.CTL,GRIPE.MAC,C.MAC,GRP???.RND
;
;PRODUCE CREF LISTING
.ASSIGN DSK LPT
.CREF
.COPY GRIPE.TMP=GRP???.RND
.RUN RUNOFF[10,7]
*GRIPE.TMP
*GRIPE.DOC
;
.DEASSIGN
.MOUNT DTA:GRIPE/VID:'GRIPE SUBMISSION TAPE'/WE
.IF (ERROR) .GOTO NOTAP
.ZERO GRIPE:
.LABEL GRIPE:GRIPE
.COPY GRIPE:=GRIPE.CTL,GRIPE.MAC,GRIPE.HLP,GRP???.RND,GRIPE.SAV
.DIRECTORY GRIPE:
.DEASSIGN
.PLEASE OPR - GET A DIRECTORY OF DTA:GRIPE AND DISMOUNT
NOTAP::
.PLEASE GRIPE SUCCESSFUL
;
;REMOVE ALL TEMPORARY FILES
%FIN: .DELETE GRIPE.REL,PIP.SHR,DIRECT.SHR,COMPIL.SHR,MACRO.SHR,LINK.SHR
.IF (ERROR) ;DON'T CARE IF FAILED
.DELETE CREF.SHR,C.MAC,JOBDAT.REL,GRIPE.TMP,LNK???.SHR
;
.PRINT /DISP:RENAME GRIPE.LST,GRIPE.MAP,GRIPE.LOG/DISP:DELETE,/COPIES:3 GRIPE.DOC,/COPIES:3 GRIPE.HLP
;
.K/F