Trailing-Edge
-
PDP-10 Archives
-
BB-Z759A-SM
-
cobol-source/dbms20.ctl
There are 26 other files named dbms20.ctl in the archive. Click here to see a list.
! UPD ID= 1464 on 12/20/83 at 3:15 PM by HOFFMAN
! DBMS20.CTL Version 6 Sep-83
! This software is furnished under a license and may only be used
! or copied in accordance with the terms of such license.
!
! Copyright (C) 1974, 1981, 1983
! by DIGITAL EQUIPMENT COPRORATION, Marlboro, Mass.
@SILENCE
! This control file will 'TAKE DSK:SETUP.CMD' upon execution.
! SETUP.CMD is an optional file for setting up an environmrnt for
! this control file. It may be used, for example, to expand the
! definition of DSK:, so that specified source files may be in
! other than the connected directory, or to expand the definition
! of SYS:, to utilize some non-default system software. For example:
!
! DEFINE DSK: DSK:,LANG:<FORT-7>,LANG:<COB-13>
! DEFINE SYS: PS:<NEW-SUBSYS>,SYS:
!
! If SETUP.CMD is not provided, all required files must appear in
! the connected directory.
!
! If applicable, rebuild the host languages before submitting this
! control file.
!
! To rebuild host language runtime support for:
! COBOL-68/74(12B) -or- COBOL(13)
! FORTRAN (6) -or- FORTRAN(7)
! @SUBMIT DBMS20
! To rebuild host language support plus:
! SCHEMA.EXE (the schema processor);
! DBMEND.EXE (backup/recovery utility);
! DBINFO.EXE (database information utility);
! FORDML.EXE (FORTRAN preprocessor);
! @SUBMIT DBMS20/TAG:DBALL
!
! NOTE: This control files does not rebuild the COBOL compiler. If it is
! necessary to do so (as is the case for the distributed
! COBOL-68/74(12B) compilers), use COBOL.CTL from the COBOL
! distribution tape, after making available the following files
! from the DBMS-20(6) tape:
!
! CMLSYM.MAC DBSDCL.MAC GENDCL.MAC STRDCL.MAC
! STRUNV.MAC DBDML.MAC DBGETF.MAC DMLERR.MAC
! DMLIO.MAC DMLVOK.MAC STRHI.REL SCHIO2.REL
!
!REQUIRED FILES: (LATEST RELEASED VERSIONS)
!
! SYS: MAKLIB.EXE LINK.EXE
! SCAN.REL WILD.REL HELPER.REL
!
! DSK: DBMS20.CTL SETUP.CMD (optional)
! SCHEM2.CMD FORDM2.CMD DBMEN2.CMD DBINF2.CMD
! DBCS28.CMD DBCS24.CMD DBCS13.CMD DBCS2F.CMD
! DBC2F7.CMD FDBM7.EXE CHKMAP.EXE
!
!
! IF BUILDING A COBOL-68(12B) SYSTEM: LIBO12.EXE, LIBO12.MAP, AND LIBOL.REL
! IF BUILDING A COBOL-74(12B) SYSTEM: C74O12.EXE, C74O12.MAP, AND C74LIB.REL
! IF BUILDING A COBOL(13) SYSTEM: COBOTS-V13.EXE, COTS13.MAP, AND COBLIB.REL
! IF BUILDING A FORTRAN(6) SYSTEM: DBMSF.EXE, DBMSF.MAP, AND FORLIB.REL
! IF BUILDING A FORTRAN(7) SYSTEM: DBMSF.EXE, AND DBMSF.MAP
!
!OUTPUT LISTINGS: DBMS20.LOG
!
; SYS: = FILES ON SYS:
! USER: = FILES SUPPLIED BY THE USER
! DSK: = FILES SUPPLIED BY DEC
! OUTPUT: SCHEMA.EXE SCHEMA.MAP
! SYS: SCAN, WILD, HELPER
! DSK: GENME1, GENMS2, SCHIO2, DDLANY, DDL20, GENIO2, STRHI
! OUTPUT: DBMEND.EXE DBMEND.MAP
! SYS: SCAN, HELPER
! DSK: GENIO2, GENME2, GENMS2, SCHIO2, MNDANY, DBMEN2, DBSANY, STRHI
! OUTPUT: DBINFO.EXE DBINFO.MAP
! SYS: SCAN, HELPER
! DSK: GENME1, GENMS2, SCHIO2, INFANY, DBSANY, DBSI20, GENIO2, STRHI
! OUTPUT: FORDML.EXE FORDML.MAP
! SYS: SCAN, WILD, HELPER
! DSK: GENME1, SCHIO2, FMLANY, STRHI
! COBOL-68(12B)
! OUTPUT: LIBOL.REL LIBO12.EXE LIBO12.MAP
! SYS: MACREL.REL
! USER: LIBSHR.REL LIBOL.REL (WITHOUT DBMS IN IT)
! DSK: DBS20.REL DBSCOB.REL DBSANY.REL SCHIO2.REL
! COBOL-74(12B)
! OUTPUT: C74LIB.REL C74O12.EXE C74O12.MAP
! SYS: MACREL.REL
! USER: C74SHR.REL C74LIB.REL (WITHOUT DBMS IN IT)
! DSK: DBS20.REL DBSCOB.REL DBSANY.REL SCHIO2.REL
! COBOL(13)
! OUTPUT: COBLIB.REL COBOTS-V13.EXE COTS13.MAP
! SYS: MACREL.REL
! USER: C8XSHR.REL COBLIB.REL (WITHOUT DBMS IN IT)
! DSK: DBS20.REL DBSCOB.REL DBSANY.REL SCHIO2.REL
! FORTRAN(6)
! OUTPUT: FORLIB.REL DBMSF.EXE DBMSF.MAP
! USER: FORLIB.REL (WITHOUT DBMS IN IT)
! DSK: DBS20.REL DBSFG.REL DBSANY.REL SCHIO2.REL
! FORTRAN(7)
! OUTPUT: DBMSF.EXE DBMSF.MAP
! USER: FORDBM.RLR
! DSK: DBS20.REL DBSFG.REL DBSANY.REL SCHIO2.REL
@REVIVE
@EXPUNGE
!MAKE A RECORD OF WHAT IS BEING USED
@DEFINE *
@
@TAKE DSK:SETUP.CMD
@INFO LOGICAL
! to skip information gathering
@GOTO NODIR
@ERROR %
@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION
@VDIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,SYS:SCAN.REL,SYS:WILD.REL,SYS:HELPER.REL,
@CHECK SEQ
@
@VDIRECT DBMS20.CTL,
@CHECK SEQ
@
@VDIRECT SCHEM2.CMD, FORDM2.CMD, DBMEN2.CMD, DBINF2.CMD, DBCS28.CMD, DBCS24.CMD, DBCS2F.CMD, DBC2F7.CMD,FDBM7.EXE,
@CHECK SEQ
@
@VDIRECT CMLERR.REL, CMLIO.REL, CMLVOK.REL, DBDML.REL, DBGETF.REL, DBMEN2.REL, DBS20.REL, DBSANY.REL, DBSI20.REL, DDL20.REL, DDLANY.REL, FMLANY.REL, GENIO2.REL, GENME1.REL, GENME2.REL, GENMS2.REL, INFANY.REL, MNDANY.REL, SCHIO2.REL, STRHI.REL,
@CHECK SEQ
@
@NOERROR
@VDIR SETUP.CMD,
@CHECK SEQ
@
NODIR::
@ERROR
@GOTO DBOTS
! DBOTS IS THE DEFAULT PATH -- JUST BUILD THE OTS
! ENTRY AT DBALL WILL BUILD THE UTILTIES AND THE OTS
DBALL::
@REVIVE
@EXPUNGE
! DBALL IS THE ENTRY POINT TO REBUILD THE UTILITIES
! DBOTS IS THE ENTRY POINT TO JUST DO THE RUN-TIME SYSTEMS
!MAKE A RECORD OF WHAT IS BEING USED
@DEFINE *
@
@TAKE DSK:SETUP.CMD
@INFO LOGICAL
! to skip information gathering
@GOTO NODIR
@ERROR %
@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION
@VDIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,SYS:SCAN.REL,SYS:WILD.REL,SYS:HELPER.REL,
@CHECK SEQ
@
@VDIRECT SCHEM2.CMD, FORDM2.CMD, DBMEN2.CMD, DBINF2.CMD, DBCS28.CMD, DBCS24.CMD, DBCS2F.CMD, DBCS25.CMD,
@CHECK SEQ
@
@VDIRECT CMLERR.REL, CMLIO.REL, CMLVOK.REL, DBDML.REL, DBGETF.REL, DBMEN2.REL, DBS20.REL, DBSANY.REL, DBSI20.REL, DDL20.REL, DDLANY.REL, FMLANY.REL, GENIO2.REL, GENME1.REL, GENME2.REL, GENMS2.REL, INFANY.REL, MNDANY.REL, SCHIO2.REL, STRHI.REL,
@CHECK SEQ
@
NODIR::
![1] Check for version file, and set appropriate VER: def
@DEFINE VER: DSK: ![1] Default
@ERROR % ![1]
@DIRECT DB20V6.VER ![1]
@IF (ERROR) @DEFINE VER: NUL: ![1] Non existant
@ERROR
! ********** SCHEMA **********
BLDSCH::
@ERROR
@EXPUNGE
@R LINK
*@VER:DB20V6.VER ![1]
*@SCHEM2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:SCHEMA
@IF (ERROR) @GOTO TRUBLE
! ********** DBMEND **********
BLDDBM::
@ERROR
@EXPUNGE
@R LINK
*@VER:DB20V6.VER ![1]
*@DBMEN2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMEND
@IF (ERROR) @GOTO TRUBLE
! ********** DBINFO **********
BLDINF::
@ERROR
@EXPUNGE
@R LINK
*@VER:DB20V6.VER ![1]
*@DBINF2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBINFO
@IF (ERROR) @GOTO TRUBLE
! ********** FORDML **********
BLDDML::
@ERROR
@EXPUNGE
@R LINK
*@VER:DB20V6.VER ![1]
*@FORDM2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:FORDML
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
DBOTS::
! DBOTS IS THE DEFAULT ENTRY POINT.
! IF YOU WANT TO REBUILD THE UTILITIES
! YOU SHOULD "@SUBMIT DBMS20/TIME:30/TAG:DBALL"
BLDC68::
! ********** COBOL-68(12B) **********
! to skip this section
!@GOTO C68OK
! attempt to find correct non-DBMS library, in search-list environmrnt
@NOERROR
@REN LIBOL.REL LIBOL.OLD-DBMS20-REL
@ERROR %
@COPY LIBOL.REL
@IF (ERROR) @COPY LIBOL.OLD-DBMS20-REL LIBOL.REL
@IF (ERROR) @!ignore...caught below
@ERROR %
@VDIR LIBOL.REL,LIBSHR.REL
@IF (ERROR) @GOTO NOC68
@ERROR
@EXPUNGE
@R MAKLIB
*CBDSTP.TMP=LIBOL/EXTRACT:(%DBSTP,DBSTP$) ![517]
*LIBOL=LIBOL/DELETE:RESOLV
*LIBOL=LIBOL/DELETE:RSVGAT
*LIBOL=LIBOL/DELETE:%DBSTP ![517]
*LIBOL=LIBOL/DELETE:DBSTP$
*COBFUN.TMP=LIBOL/EXTR:COBFUN
*LIBOL=LIBOL/DELETE:COBFUN
*LIBOL=LIBOL,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND, -
*SCHIO2/APPEND,CBDSTP.TMP/APPEND ![517]
*LIBOL=LIBOL/INDEX
@DEL CBDSTP.TMP,COBFUN.TMP ![517]
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@NOERROR
@COPY LIBO12.EXE LIBO12.OLD-DBMS20-EXE
@ERROR
@R LINK
*@DBCS28.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:LIBO12 0 1, 561 577, 600 675
@IF (ERROR) @GOTO TRUBLE
! to skip the map check
@GOTO C68OK
@ERROR
@RU CHKMAP ; local link checker
*LIBO12.MAP
*577
*675
@IF (ERROR) @GOTO TRUBLE
@GOTO C68OK
NOC68::
@MS SEND
*.
*
*DBMS20.CTL
* % Skipping COBOL-68(12B) build...see log for missing files.
=
C68OK::
@EXPUNGE
BLDC74::
! ********** COBOL-74(12B) **********
! to skip this section
!@GOTO C74OK
! attempt to find correct non-DBMS library, in search-list environmrnt
@NOERROR
@REN C74LIB.REL C74LIB.OLD-DBMS20-REL
@ERROR %
@COPY C74LIB.REL
@IF (ERROR) @COPY C74LIB.OLD-DBMS20-REL C74LIB.REL
@IF (ERROR) @!ignore...caught below
@ERROR %
@VDIR C74LIB.REL,C74SHR.REL
@IF (ERROR) @GOTO NOC74
@ERROR
@EXPUNGE
@R MAKLIB
*CBDSTP.TMP=C74LIB/EXTRACT:(%DBSTP,DBSTP$) ![517]
*C74LIB=C74LIB/DELETE:RESOLV
*C74LIB=C74LIB/DELETE:RSVGAT
*C74LIB=C74LIB/DELETE:%DBSTP ![517]
*C74LIB=C74LIB/DELETE:DBSTP$
*COBFUN.TMP=C74LIB/EXTR:COBFUN
*C74LIB=C74LIB/DELETE:COBFUN
*C74LIB=C74LIB,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND, -
*SCHIO2/APPEND,CBDSTP.TMP/APPEND ![517]
*C74LIB=C74LIB/INDEX
@DEL CBDSTP.TMP,COBFUN.TMP ![517]
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@NOERROR
@COPY C74O12.EXE C74O12.OLD-DBMS20-EXE
@ERROR
@R LINK
*@DBCS24.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:C74O12 0 1,547 575,600 675 ![6%541]
@IF (ERROR) @GOTO TRUBLE
! to skip map check
@GOTO C74OK
@ERROR
@RU CHKMAP ; local link checker
*C74O12.MAP
*575
*675
@IF (ERROR) @GOTO TRUBLE
@GOTO C74OK
NOC74::
@MS SEND
*.
*
*DBMS20.CTL
* % Skipping COBOL-74(12B) build...see log for missing files.
=
C74OK::
@ERROR
@EXPUNGE
BLDC13::
! ********** COBOL(13) **********
! to skip this section
!@GOTO C13OK
! attempt to find correct non-DBMS library, in search-list environmrnt
@NOERROR
@REN COBLIB.REL COBLIB.OLD-DBMS20-REL
@ERROR %
@COPY COBLIB.REL
@IF (ERROR) @COPY COBLIB.OLD-DBMS20-REL COBLIB.REL
@IF (ERROR) @!ignore...caught below
@ERROR %
@VDIR COBLIB.REL,C8XSHR.REL
@IF (ERROR) @GOTO NOC13
@ERROR
@EXPUNGE
@R MAKLIB
*CBDSTP.TMP=COBLIB/EXTRACT:(DBSTUB,DBMS.,%DBSTP,DBMVR.)
*COBLIB=COBLIB/DELETE:(DBSTUB,DBMS.,%DBSTP,DBMVR.)
*COBFUN.TMP=COBLIB/EXTRACT:COBFUN
*COBLIB=COBLIB/DELETE:COBFUN
*COBLIB=COBLIB,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND, -
*SCHIO2/APPEND,CBDSTP.TMP/APPEND
*COBLIB=COBLIB/INDEX
@DEL CBDSTP.TMP,COBFUN.TMP
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@NOERROR
@COPY COBOTS-V13.EXE COBOTS-V13.OLD-DBMS20-EXE
@ERROR
@R LINK
*@DBCS13.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:COBOTS-V13 0 1,547 575,600 675 ![6%541]
@IF (ERROR) @GOTO TRUBLE
! to skip map check
@GOTO C13OK
@ERROR
@RU CHKMAP ; local link checker
*COTS13.MAP
*575
*675
@IF (ERROR) @GOTO TRUBLE
@GOTO C13OK
NOC13::
@MS SEND
*.
*
*DBMS20.CTL
* % Skipping COBOL(13) build...see log for missing files.
=
C13OK::
@ERROR
@EXPUNGE
CHKFOR::
! check which version of FORTRAN to support
@ERROR %
@VDIR FORDBM.RLR
@IF (NOERROR) @GOTO BLDF7
BLDF6::
! ********** FORTRAN(6) **********
! to skip this section
@GOTO F6OK
! attempt to find correct non-DBMS library, in search-list environmrnt
@NOERROR
@REN FORLIB.REL FORLIB.OLD-DBMS20-REL
@ERROR %
@COPY FORLIB.REL
@IF (ERROR) @COPY FORLIB.OLD-DBMS20-REL FORLIB.REL
@IF (ERROR) @!ignore...caught below
@ERROR %
@VDIR FORLIB.REL
@IF (ERROR) @GOTO NOF6
@ERROR
@EXPUNGE
@R MAKLIB
*FORLIB=FORLIB/DELETE:(FORDBM,FORDST)
*FORLIB=FORLIB,DBSFG/APPEND,DBS20/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*FORLIB=FORLIB/INDEX
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@NOERROR
@COPY DBMSF.EXE DBMSF.OLD-DBMS20-EXE
@ERROR
@LINK
*@DBCS2F.CMD
@GET DBMSF.EXE
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMSF.EXE 700 740
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@GOTO F6OK
NOF6::
@MS SEND
*.
*
*DBMS20.CTL
* % Skipping FORTRAN(6) build...see log for missing files.
=
F6OK::
@EXPUNGE
! did 6, skip 7
@GOTO ALLDUN
BLDF7::
! ********** FORTRAN(7) **********
! to skip this section
@GOTO F7OK
@ERROR %
@VDIR FORDBM.RLR
@IF (ERROR) @GOTO NOF7
@ERROR
@EXPUNGE
@R MAKLIB
DBMSF=DBSFG,DBSANY/APPEND,DBS20/APPEND,SCHIO2/APPEND
DBMSF=DBMSF/DELETE:(DBFLI.,DBF5A.)
DBMSF=DBMSF/MASTER:(DBPORT),FORDBM.RLR/INSERT
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@RU FDBM7
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@NOERROR
@COPY DBMSF.EXE DBMSF.OLD-DBMS20-EXE
@ERROR
@LINK
*@DBC2F7.CMD
@GET DBMSF.EXE
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMSF.EXE 700 765
@IF (ERROR) @GOTO TRUBLE
@GOTO F7OK
NOF7::
@MS SEND
*.
*
*DBMS20.CTL
* % Skipping FORTRAN(7) build...see log for missing files.
=
F7OK::
@EXPUNGE
ALLDUN::
! ************ IF here, everything is O.K. *************
!
@NOERROR
@VDIR SCHEMA.*,FORDML.*,DBMEND.*,DBINFO.*,
@CHECK SEQ
@
@VDIR LIBOL.REL,LIBO12.*,
@CHECK SEQ
@
@VDIR C74LIB.REL,C74O12.*,
@CHECK SEQ
@
@VDIR COBLIB.REL,COBOTS-V13.EXE,COTS13.MAP,
@CHECK SEQ
@
@VDIR FORLIB.REL,DBMSF.EXE,DBMSF.MAP,
@CHECK SEQ
@
!
@DEL *.OLD-DBMS20-REL,*.OLD-DBMS20-EXE
@EXPUNGE
!
@MS SEND
*.
*
*DBMS20.CTL
* DBMS20.CTL finished
=
@MODIFY BATCH */DEPEND:-1
@GOTO ENDOF
! ********* All errors fall through here ************
%ERR::
@GOTO TRUBLE
%TERR::
@GOTO TRUBLE
TRUBLE::
@MS SEND
*.
*
*DBMS20.CTL
* FAILURE IN DBMS20.CTL
=
@REN *.OLD-DBMS20-REL *.REL
@REN *.OLD-DBMS20-EXE *.EXE
! ********** everyone comes here ***********
ENDOF::
@EXPUNGE
@LOGO
! [ END OF DBMS20.CTL ]